Delphi Откройте URL веб-сайт в браузере по умолчанию из приложения Firemonkey

[Lomanu4]

Открытие веб-страницы с помощью кнопки - это классика программирования, поскольку Интернет есть повсюду. Для этого, как правило, необходимо позвонить в операционную систему с просьбой открыть требуемый ресурс «url». Затем он запускает браузер по умолчанию и отображает запрошенную страницу, если она существует.
Однако эту простую функцию не всегда легко настроить.
С Firemonkey это действительно нужно делать для всех управляемых платформ: Windows, OS X, iOS и Android. Конечно, у каждого свой способ сделать системный вызов.
Когда я задал себе вопрос, я сначала безуспешно поискал документацию по RAD Studio 10 Seattle, а затем снова обратился к Google. Существует множество форумов, посвященных этой проблеме, но ни одно из предлагаемых решений не является полным или текущим (некоторые модули, имена и функции которых были изменены, были перемещены между последними версиями RAD Studio или Delphi).
Собрав вместе части кода, которые работают, я придумал этот модуль, который вам просто нужно включить в проект Firemonkey.

unit u_urlOpen;

interface

uses
  System.SysUtils, System.Types, System.UITypes, System.Classes,
  System.Variants,
{$IF Defined(IOS)}
  macapi.helpers, iOSapi.Foundation, FMX.helpers.iOS;
{$ELSEIF Defined(ANDROID)}
Androidapi.JNI.GraphicsContentViewText,
  Androidapi.JNI.Net,
   Androidapi.JNI.App,
  Androidapi.helpers;
{$ELSEIF Defined(MACOS)}
Posix.Stdlib;
{$ELSEIF Defined(MSWINDOWS)}
Winapi.ShellAPI, Winapi.Windows;
{$ENDIF}

type
  tUrlOpen = class
    class procedure Open(URL: string);
  end;

implementation

class procedure tUrlOpen.Open(URL: string);
{$IF Defined(ANDROID)}
var
  Intent: JIntent;
{$ENDIF}
begin
{$IF Defined(ANDROID)}
  Intent := TJIntent.Create;
  Intent.setAction(TJIntent.JavaClass.ACTION_VIEW);
  Intent.setData(StrToJURI(URL));
  tandroidhelper.Activity.startActivity(Intent);
  // SharedActivity.startActivity(Intent);
{$ELSEIF Defined(MSWINDOWS)}
  ShellExecute(0, 'OPEN', PWideChar(URL), nil, nil, SW_SHOWNORMAL);
{$ELSEIF Defined(IOS)}
  SharedApplication.OpenURL(StrToNSUrl(URL));
{$ELSEIF Defined(MACOS)}
  _system(PAnsiChar('open ' + AnsiString(URL)));
{$ENDIF}
end;

end.

Вызов осуществляется просто:

tUrlOpen.Open('http://www.developpeur-pascal.fr');